mirror of
https://github.com/syncthing/syncthing-android.git
synced 2025-01-09 19:53:33 +00:00
c224bcb04a
* Add push APK to device after build script * Fix typo in SyncthingService comment * Refactor SettingsActivity - updatePersistentNotification Call updatePersistentNotification after the settings screen was left and not when the user toggles the alwaysRunInBackgroundAsAService checkbox. * Automatically start app if push-to-device is enabled * Remove PREF_NOTIFICATION_TYPE * Only push APK to device if build succeeded * Fix notifications and foreground service start/stop * Use startForegroundService on Android 8+ * Fix startActivity called from non-Activity context (fixes #80) * Fix comment
94 lines
3.1 KiB
Groovy
94 lines
3.1 KiB
Groovy
apply plugin: 'com.android.application'
|
|
apply plugin: 'com.github.ben-manes.versions'
|
|
apply plugin: 'com.github.triplet.play'
|
|
|
|
dependencies {
|
|
implementation 'eu.chainfire:libsuperuser:1.0.0.201704021214'
|
|
implementation 'com.android.support:design:28.0.0'
|
|
implementation 'com.google.zxing:android-integration:3.3.0'
|
|
implementation 'com.google.code.gson:gson:2.8.2'
|
|
implementation 'org.mindrot:jbcrypt:0.4'
|
|
implementation 'com.google.guava:guava:23.6-android'
|
|
implementation 'com.annimon:stream:1.1.9'
|
|
implementation 'com.android.volley:volley:1.1.0'
|
|
implementation 'com.android.support.constraint:constraint-layout:1.1.3'
|
|
implementation 'com.google.dagger:dagger:2.14.1'
|
|
annotationProcessor "com.google.dagger:dagger-compiler:2.14.1"
|
|
androidTestImplementation 'com.android.support.test:rules:1.0.2'
|
|
androidTestImplementation 'com.android.support:support-annotations:28.0.0'
|
|
}
|
|
|
|
android {
|
|
// Changes to these values need to be reflected in `.travis.yml`
|
|
compileSdkVersion 28
|
|
buildToolsVersion '28.0.2'
|
|
|
|
buildTypes.debug.applicationIdSuffix ".debug"
|
|
dataBinding.enabled = true
|
|
|
|
playAccountConfigs {
|
|
defaultAccountConfig {
|
|
jsonFile = file(System.getenv("SYNCTHING_RELEASE_PLAY_ACCOUNT_CONFIG_FILE") ?: 'keys.json')
|
|
}
|
|
}
|
|
defaultConfig {
|
|
applicationId "com.github.catfriend1.syncthingandroid"
|
|
minSdkVersion 16
|
|
targetSdkVersion 26
|
|
versionCode 4166
|
|
versionName "0.14.51.3"
|
|
testApplicationId 'com.github.catfriend1.syncthingandroid.test'
|
|
testInstrumentationRunner 'android.support.test.runner.AndroidJUnitRunner'
|
|
playAccountConfig = playAccountConfigs.defaultAccountConfig
|
|
}
|
|
|
|
signingConfigs {
|
|
release {
|
|
storeFile = {
|
|
def path = System.getenv("SYNCTHING_RELEASE_STORE_FILE")
|
|
return (path) ? file(path) : null
|
|
}()
|
|
storePassword System.getenv("SIGNING_PASSWORD") ?: ""
|
|
keyAlias System.getenv("SYNCTHING_RELEASE_KEY_ALIAS") ?: ""
|
|
keyPassword System.getenv("SIGNING_PASSWORD") ?: ""
|
|
}
|
|
}
|
|
buildTypes {
|
|
release {
|
|
signingConfig = signingConfigs.release.storeFile ? signingConfigs.release : null
|
|
}
|
|
debug {
|
|
gradle.buildFinished {
|
|
buildResult -> if (!buildResult.failure) {
|
|
pushToDevice.execute()
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
compileOptions {
|
|
sourceCompatibility JavaVersion.VERSION_1_8
|
|
targetCompatibility JavaVersion.VERSION_1_8
|
|
}
|
|
}
|
|
|
|
play {
|
|
jsonFile = file(System.getenv("SYNCTHING_RELEASE_PLAY_ACCOUNT_CONFIG_FILE") ?: 'keys.json')
|
|
uploadImages = false
|
|
track = 'beta'
|
|
}
|
|
|
|
/**
|
|
* Some languages are not supported by Google Play, so we ignore them.
|
|
*/
|
|
task deleteUnsupportedPlayTranslations(type: Delete) {
|
|
delete 'src/main/play/nn'
|
|
delete 'src/main/play/el-EL'
|
|
delete 'src/main/play/nb'
|
|
delete 'src/main/play/en/'
|
|
}
|
|
|
|
task pushToDevice(type: Exec) {
|
|
executable = 'python'
|
|
args = ['-u', './push-to-device.py']
|
|
}
|