mirror of
https://github.com/syncthing/syncthing-android.git
synced 2024-11-23 04:41:16 +00:00
43555671c1
Bumps [gson](https://github.com/google/gson) from 2.8.8 to 2.8.9. - [Release notes](https://github.com/google/gson/releases) - [Changelog](https://github.com/google/gson/blob/master/CHANGELOG.md) - [Commits](https://github.com/google/gson/compare/gson-parent-2.8.8...gson-parent-2.8.9) --- updated-dependencies: - dependency-name: com.google.code.gson:gson dependency-type: direct:production update-type: version-update:semver-patch ... Signed-off-by: dependabot[bot] <support@github.com>
98 lines
3.3 KiB
Groovy
98 lines
3.3 KiB
Groovy
plugins {
|
|
id 'com.android.application'
|
|
id 'com.github.ben-manes.versions'
|
|
id 'com.github.triplet.play' version '2.8.0'
|
|
}
|
|
|
|
dependencies {
|
|
implementation 'eu.chainfire:libsuperuser:1.1.0.202004101746'
|
|
implementation 'com.google.android.material:material:1.4.0'
|
|
implementation 'com.google.code.gson:gson:2.8.9'
|
|
implementation 'org.mindrot:jbcrypt:0.4'
|
|
implementation 'com.google.guava:guava:31.0.1-android'
|
|
implementation 'com.annimon:stream:1.2.2'
|
|
implementation 'com.android.volley:volley:1.2.1'
|
|
implementation 'commons-io:commons-io:2.11.0'
|
|
|
|
implementation ('com.journeyapps:zxing-android-embedded:4.1.0') { transitive = false }
|
|
implementation 'com.google.zxing:core:3.4.1'
|
|
|
|
implementation 'androidx.constraintlayout:constraintlayout:2.0.4'
|
|
implementation 'com.google.dagger:dagger:2.40.5'
|
|
annotationProcessor 'com.google.dagger:dagger-compiler:2.40.5'
|
|
androidTestImplementation 'androidx.test:rules:1.4.0'
|
|
androidTestImplementation 'androidx.annotation:annotation:1.2.0'
|
|
}
|
|
|
|
android {
|
|
// Changes to these values need to be reflected in `../docker/Dockerfile`
|
|
compileSdkVersion 30
|
|
buildToolsVersion '30.0.0'
|
|
ndkVersion = "${ndkVersionShared}"
|
|
|
|
buildTypes.debug.applicationIdSuffix ".debug"
|
|
buildFeatures.dataBinding = true
|
|
|
|
playConfigs {
|
|
defaultAccountConfig {
|
|
serviceAccountCredentials = file(System.getenv("SYNCTHING_RELEASE_PLAY_ACCOUNT_CONFIG_FILE") ?: 'keys.json')
|
|
}
|
|
}
|
|
defaultConfig {
|
|
applicationId "com.nutomic.syncthingandroid"
|
|
minSdkVersion 16
|
|
targetSdkVersion 30
|
|
versionCode 4290
|
|
versionName "1.18.4-rc.2"
|
|
testApplicationId 'com.nutomic.syncthingandroid.test'
|
|
testInstrumentationRunner 'androidx.test.runner.AndroidJUnitRunner'
|
|
}
|
|
|
|
signingConfigs {
|
|
release {
|
|
storeFile = {
|
|
def path = System.getenv("SYNCTHING_RELEASE_STORE_FILE")
|
|
return (path) ? file(path) : null
|
|
}()
|
|
storePassword System.getenv("SIGNING_PASSWORD") ?: ""
|
|
keyAlias System.getenv("SYNCTHING_RELEASE_KEY_ALIAS") ?: ""
|
|
keyPassword System.getenv("SIGNING_PASSWORD") ?: ""
|
|
}
|
|
}
|
|
buildTypes {
|
|
release {
|
|
signingConfig = signingConfigs.release.storeFile ? signingConfigs.release : null
|
|
}
|
|
debug {
|
|
debuggable true
|
|
jniDebuggable true
|
|
renderscriptDebuggable true
|
|
minifyEnabled false
|
|
}
|
|
}
|
|
|
|
compileOptions {
|
|
sourceCompatibility JavaVersion.VERSION_1_8
|
|
targetCompatibility JavaVersion.VERSION_1_8
|
|
}
|
|
}
|
|
|
|
play {
|
|
serviceAccountCredentials = file(System.getenv("SYNCTHING_RELEASE_PLAY_ACCOUNT_CONFIG_FILE") ?: 'keys.json')
|
|
track = 'beta'
|
|
}
|
|
|
|
/**
|
|
* Some languages are not supported by Google Play, so we ignore them.
|
|
*/
|
|
task deleteUnsupportedPlayTranslations(type: Delete) {
|
|
delete 'src/main/play/listings/de_DE/'
|
|
delete 'src/main/play/listings/el-EL/'
|
|
delete 'src/main/play/listings/en/'
|
|
delete 'src/main/play/listings/eo/'
|
|
delete 'src/main/play/listings/eu/'
|
|
delete 'src/main/play/listings/nb/'
|
|
delete 'src/main/play/listings/nl_BE/'
|
|
delete 'src/main/play/listings/nn/'
|
|
delete 'src/main/play/listings/ta/'
|
|
}
|