ensichat/android/build.gradle

apply plugin: 'com.android.application'
apply plugin: 'jp.leafytree.android-scala'

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "jp.leafytree.gradle:gradle-android-scala-plugin:1.4"
    }
}

dependencies {
    compile 'com.android.support:design:23.1.1'
    compile 'com.android.support:multidex:1.0.1'
    compile 'org.scala-lang:scala-library:2.11.7'
    compile 'com.mobsandgeeks:adapter-kit:0.5.3'
    compile 'com.google.zxing:android-integration:3.2.1'
    compile 'com.google.zxing:core:3.2.1'
    compile project(path: ':core')
    androidTestCompile 'com.android.support:multidex-instrumentation:1.0.1',
            { exclude module: 'multidex' }
}

// RtlHardcoded behaviour differs between target API versions. We only care about API 15.
preBuild.doFirst {
    android.applicationVariants.each { variant ->
        if (variant.name == 'devDebug' || variant.name == 'devRelease') {
            println variant.name
            android.lintOptions.disable 'RtlHardcoded'
        }
    }
}

android {
    compileSdkVersion 23
    buildToolsVersion "22.0.1"

    defaultConfig {
        applicationId "com.nutomic.ensichat"
        targetSdkVersion 23
        versionCode project.properties.versionCode.toInteger()
        versionName project.properties.versionName
        multiDexEnabled true
        testInstrumentationRunner "com.android.test.runner.MultiDexTestRunner"
    }

    buildTypes.debug {
        applicationIdSuffix ".debug"
        testCoverageEnabled true
    }

    // Increasing minSdkVersion reduces compilation time for MultiDex.
    productFlavors {
        dev.minSdkVersion 21
        rel.minSdkVersion 15
    }
}